Quit[];

A Michaelis-Menten modell

Ez a modell minden bevezető biokémia tankönyvben szerepel, ajánljuk Keleti T. alább idézett - angolul is megjelent - könyvét.

A vizsgálandó folyamat

a folyamat (enzimkinetikában) szokásos jelölése: E+S(Underoverscript[⇌, (Subscript[k, -1]), (Subscript[k, 1])])C(Overscript[->, (Subscript[k, 2])])E+P

a modell számtalan variációja ismert, lásd pl. Keleti (1985); a legegyszerűbb módosításnál a második lépést is megfordíthatónak veszik

E egy enzimet (katalizátorfehérje) jelöl

S ennek szubsztrátja, azaz az az anyag, amelyet az enzim átalakít

C az enzim és a szubsztrát által alkotott ideiglenes komplex molekula

P termék (produktum)

(Subscript[k, 1]),(Subscript[k, -1]),(Subscript[k, 2])>0 az átalakulások sebességére jellemző pozitív számok, a reakciósebességi együtthatók

A modell

eq0={
e'[t]== -(Subscript[k, 1])e[t]s[t]+(Subscript[k, -1])c[t]+(Subscript[k, 2])c[t],
s'[t]== -(Subscript[k, 1])e[t]s[t]+(Subscript[k, -1])c[t],
c'[t]==(Subscript[k, 1])e[t]s[t]-(Subscript[k, -1])c[t]-(Subscript[k, 2])c[t],
p'[t]==(Subscript[k, 2])c[t]};
ini0={e[0]==e0,s[0]==s0,c[0]==0,p[0]==0};

Jelölések

Ahol:

e(t) az enzim mennyisége a t időpontban

s(t) a szubsztrát mennyisége a t időpontban

c(t) az enzim-szubsztrát komplex mennyisége a t időpontban

p(t) a termék (produktum) mennyisége a t időpontban

(Subscript[k, 1]),(Subscript[k, -1]),(Subscript[k, 2])>0 a sebességi együtthatók

Az egyszerűsített modell

Mivel az egyenletek között fennáll két lineáris összefüggés:

{e'[t]+c'[t]==0,s'[t]+c'[t]+p'[t]==0};

vagyis

konzerv={e[t]+c[t]==e0,s[t]+c[t]+p[t]==s0};

sc=First@Solve[konzerv,{s[t],c[t]}]

(amelyek jelentése, hogy a különböző alakban jelenlévő enzim és a szubsztrát teljes mennyisége állandó), ezért elegendő az alábbival foglalkozni:

eq[e0_,s0_]:={
e'[t]== -(Subscript[k, 1])e[t](e[t]-e0-p[t]+s0)+((Subscript[k, -1])+(Subscript[k, 2]))(e0-e[t]),p'[t]== (Subscript[k, 2])(e0-e[t])};ini[e0_]:={e[0]==e0,p[0]==0};

Ε[e_,p_]:=-(Subscript[k, 1])e(e-e0-p+s0)+((Subscript[k, -1])+(Subscript[k, 2]))(e0-e);Π[e_,p_]:= (Subscript[k, 2])(e0-e);

eq[e0,s0]=={e'[t]==Ε[e[t],p[t]],p'[t]==Π[e[t],p[t]]}

Egyensúlyi helyzet (vagy stacionárius pont)

stac=Solve[{0==Ε[e,p],0==Π[e,p]},{e,p}][[1]]

Tehát az enzim (hiszen katalizátor) a folyamat végére regenerálódik, az összes szubsztrátból pedig termék lesz.

E:=(e0,s0)

Pontos megoldása

ClearAll[param,par];
param={(Subscript[k, 1])->100,(Subscript[k, -1])->1,(Subscript[k, 2])->1,e0->1,s0->10};
par={(Subscript[k, 1])->100,(Subscript[k, -1])->1,(Subscript[k, 2])->1};

ClearAll[nds];nds[e0_,s0_]:=NDSolve[(Join[eq[e0,s0],ini[e0]]/.par),{e,p},{t,0,25}][[1]]

pl=Plot[Evaluate[{2e[t],s[t]/.sc,2c[t]/.sc,p[t]}/.param/.nds[1,10]],{t,0,15},Frame->True,FrameLabel->{Style["idő",Italic,16],Style["koncentració",Italic,16]},PlotStyle->{Directive[{Blue,Thick}],Directive[{Green,Thick}],Directive[Brown,Thick,Dashed],Directive[Red,Thick]},Epilog->First@Graphics[{Text[Style["E",16,Blue],{10.5,2}],Text[Style["S",16,Green],{3,7}],Text[Style["ES",16,Brown],{3,1.4}],Text[Style["P",16,Red],{10.5,8.5}]}],PlotLabel->"Az egyes anyagfajták koncentrációjának\n időbeli változása"]

ParametricPlot[Evaluate[{e[t],p[t]}/.param/.nds[1,10]],{t,0,15},AxesLabel->{Style["e(t)",Italic,16],Style["p(t)",Italic,16]},PlotStyle->{Directive[{LightGray,Thick}]},AspectRatio->1,Epilog->First@Graphics[{Arrow[{{0.6,9.6},{0.7,9.70}}],Arrow[{{0.6,0},{0.5,0}}],Arrow[{{0.002,4},{0.005,5}}]}],PlotLabel->"Trajektóriák a fázissíkon"]

sp=StreamPlot[{Ε[e,s],Π[e,s]}/.param,{e,0,2},{s,8,12},AxesOrigin->{0,0},VectorScale->0.1,AxesLabel->{e,s},FrameLabel->{"E","S"},Prolog->First@Graphics[{PointSize->Large,Red,Point[{e0,s0}/.param]}],PlotLabel->"Iránymező a stacionárius ponttal\n" ]

Ez is egy szokásos ábra:

pp=ParametricPlot[Evaluate[{{s[t]/.sc,p'[t]},{(((Subscript[k, 2])+(Subscript[k, -1]))/(Subscript[k, 1])),((t-6)/29)}}/.param/.nds[1,10]],{t,6,25},AspectRatio->1,AxesOrigin->{0,0},AxesLabel->{Style["s(t)",Italic,16],Style["v(t)",Italic,16]},Epilog->First@Graphics[{Text[Style["(Subscript[K, M]):=(((Subscript[k, 2]) + (Subscript[k, -1]))/(Subscript[k, 1]))",12],{0.022,0.1}]}]]

Megjegyzések

Látszik, hogy E relatíve aszimptotikusan stabilis

A szokásos közelítés

Az első ábrán szépen látható, hogy az ES enzim-szubsztrát komplex hosszú időn át állandó. Elkészítjük ugyanezt az ábrát úgy is, hogy pontos állandóságot feltételezünk, vagyis alkalmazzuk a kvázistacionárius koncentráció hipotézisét, amit Bodenstein-elvnek is szokás nevezni. Az elv heurisztikus enzimkinetikai alkalmazása Michaelis és Menten nyomán Briggs és Haldane érdeme, pontos megalapozását Tyihonov tételére alapozva Heineken, Tsuchiya és Aris adta meg.

eq1={
e'[t]== -(Subscript[k, 1])e[t]s[t]+(Subscript[k, -1])c[t]+(Subscript[k, 2])c[t],
s'[t]== -(Subscript[k, 1])e[t]s[t]+(Subscript[k, -1])c[t],
0==(Subscript[k, 1])e[t]s[t]-(Subscript[k, -1])c[t]-(Subscript[k, 2])c[t],
p'[t]==(Subscript[k, 2])c[t]};
ini1={e[0]==e0,s[0]==s0,c[0]==0,p[0]==0};

ClearAll[dae];dae=NDSolve[Join[eq1,ini1]/.param,{e[t],s[t],c[t],p[t]},{t,0,25}][[1]]//Quiet;

sz=Plot[Evaluate[{2e[t],s[t],2c[t],p[t]}/.dae],{t,0,15},Frame->True,FrameLabel->{Style["idő",Italic,16],Style["koncentráció",Italic,16]},PlotStyle->{Directive[{Blue,Thick}],Directive[{Green,Thick}],Directive[Brown,Thick,Dashed],Directive[Red,Thick]},PlotLabel->"A szinguláris perturbáció eredménye",Epilog->First@Graphics[{Text[Style["E",16,Blue],{10,4}],Text[Style["S",16,Green],{1,1}],Text[Style["ES",16,Brown],{1,20}],Text[Style["P",16,Red],{10,12}]}]]

GraphicsRow[{pl,sz},ImageSize->600]

pl=Plot[(((Subscript[k, 2])e0 s)/((((Subscript[k, -1])+(Subscript[k, 2]))/(Subscript[k, 1]))+s))/.param,{s,0,0.05},AspectRatio->1,AxesOrigin->{0,0},AxesLabel->{Style["s",Italic,16],Style["v(s)",Italic,16]},Epilog->First@Graphics[{Line[{{(((Subscript[k, 2])+(Subscript[k, -1]))/(Subscript[k, 1])),0},{(((Subscript[k, 2])+(Subscript[k, -1]))/(Subscript[k, 1])),0.5}}/.par],Text[Style["(Subscript[K, M]):=(((Subscript[k, 2]) + (Subscript[k, -1]))/(Subscript[k, 1]))",12],{0.022,0.1}]}]]

GraphicsRow[{pp,pl}]

Az első ábra a megoldást mutatja a fázissíkon, a második pedig a szokásos közelítésben azt, hogy hogyan függ a termék keletkezésének sebessége a szubsztrát mennyiségétől. Tanulságos ezeket egymásra tenni:

Show[pl,pp]

Programozás

Figyeljük meg, hogy mivel a redukált jobb oldalak függenek a kezdeti koncentrációktól, ezért bonyolultabban kellett definiálnunk az eq és az ini függvényt.

Feladatok

Elemezzünk bonyolultabb enzimkinetikai rendszereket, a paramétereket a biokémiai irodalomból véve.

Hivatkozások

Heineken, F.; Tsuchiya, H. and R. Aris, R.: On the mathematical status of the pseudo-steady-state hypothesis of biochemical kinetics, Math. Biosci. 1 (1967), 95–113.

Keleti T.: Enzimkinetika, Tankönyvkiadó, Budapest, 1985.

Vasil’ eva, A. B.: The development of the theory of ordinary differential equations with a small parameter multiplying the highest derivative during the period 1966–1976, UMN, 1976, 31 : 6 (192), 102–122.

Vasil’ eva, A. B., Volosov, V. M.: The work of Tikhonov and his pupils on ordinary differential equations containing a small parameter, UMN, 1967, 22 : 2 (134), 149–168.

Roussel, M. R.: Singular perturbation theory, (June 21, 2004).