Quit[];

Kolmogorov-rendszerek 3.

Egy zsákmányfajból és két ragadozófajból álló modell (m=1,n=2): arányfüggő eset

A modell leírását lásd a hivatkozásoknál megadott cikkben.

A modell

ClearAll[eq,i,j,m,n,ini];eqpray[i_,m_,n_]:=(Subscript[x, i])'[t]== (Subscript[x, i])[t](Subscript[F, i])@@Join[Array[(Subscript[x, #])[t]&,m],Array[(Subscript[y, #])[t]&,n]];
eqpred[j_,m_,n_]:=(Subscript[y, j])'[t]== (Subscript[y, j])[t](Subscript[G, j])@@Join[Array[(Subscript[x, #])[t]&,m],Array[(Subscript[y, #])[t]&,n]];
inipray[i_]:=(Subscript[x, i])[0]==(Subscript[x0, i]);inipred[j_]:=(Subscript[y, j])[0]==(Subscript[y0, j]);

Tömören:

ivp[m_,n_]:=Join[Array[eqpray[#,m,n]&,m],Array[eqpred[#,m,n]&,n],
Array[inipray[#]&,m],Array[inipred[#]&,n]]

Ennek speciális esetével fogunk foglalkozni:

ivp[1,2]

A specialitás abban áll, hogy a jobb oldalon racionális függvények szerepelnek.

ClearAll[K,r];
ϕ[x_,y1_,y2_,K_,a1_,a2_,μ1_,μ2_,r_]:=r(1-(x/K))-((μ1 y1)/(a1 y1+x))-((μ2 y2)/(a2 y2+x));
(Subscript[F, 1])[x_,y1_,y2_]:=ϕ[x,y1,y2,K,a1,a2,μ1,μ2,r];
(Subscript[γ, 1])[x_,y1_,a1_,μ1_,d1_]:=((μ1 x)/(a1 y1+x))-d1;
(Subscript[γ, 2])[x_,y2_,a2_,μ2_,d2_]:=((μ2 x)/(a2 y2+x))-d2;
(Subscript[G, 1])[x_,y1_,y2_]:=(Subscript[γ, 1])[x,y1,a1,μ1,d1];(Subscript[G, 2])[x_,y1_,y2_]:=(Subscript[γ, 2])[x,y2,a2,μ2,d2];

{(Subscript[F, 1])[x,y1,y2],(Subscript[G, 1])[x,y1,y2],(Subscript[G, 2])[x,y1,y2]}

akkor az egyenletek és a kezdeti feltételek:

ivp[1,2]//Column

Jelölések

ahol:

r(1-((Subscript[x, 1])/K)) a zsákmányfaj logisztikus növekedési rátája, és

r>0 a belső növekedési ráta (azaz születési és a halálozási ráta különbsége)

K>0 a környezet fenntartóképessége a zsákmányfaj szempontjából

(((Subscript[μ, i]) (Subscript[x, 1])(Subscript[y, i]))/((Subscript[a, i])(Subscript[y, i])+(Subscript[x, 1]))) az úgynevezett Holling-féle funkcionális válasz arányfüggés esetén, és

(Subscript[μ, i])>0 az i-edik ragadozófaj maximális növekedési rátája

(Subscript[a, i])>0 az i-edik  ragadozófaj félszaturációs állandója, jelentése kissé módosul

a ragadozó létszámával arányosan csökkenti a zsákmányfaj növekedési rátáját

(Subscript[d, i])>0 az i-edik ragadozófaj mortalitása

A zsákmány nullavonal-felülete

Igazodva a Kiss, K. Kovács, S. (2008) cikk jelöléseihez a zsákmány nullavonal-felülete így kapható meg.

ClearAll[parama,sha,stac,r,K,m1,a1,m2,a2];
parama[R_]:={r->R,K->0.1`,m1->16,a1->4,m2->18,a2->2};
stac=Solve[{r (1-(x/K))-y1 m1(1/(a1 y1+x))-y2 m2(1/(a2 y2+x))==0,m1(x/(a1 y1+x))-d1 ==0,m2(x/(a2 y2+x))-d2==0},{x,y1,y2}];
sha[R_,xig_,y1ig_,y2ig_,plp_:2]:=Show[ContourPlot3D[((r x (1-(x/K))-y1 m1(x/(a1 y1+x))-y2 m2(x/(a2 y2+x)))/.parama[R])==0,{x,0,xig},{y1,0,y1ig},{y2,0,y2ig},AxesLabel->{x,(Subscript[y, 1]),(Subscript[y, 2])},PlotPoints->plp],Graphics3D[{RGBColor[0,0,0],Sphere[({x,y1,y2}/.stac/.parama[R]/.{d1->8,d2->12})[[1]],0.002]}],PlotLabel:>ToString[parama[R]]<>"\n",LabelStyle->Directive[Bold]]

sha[3,0.1,0.01,0.005]

Ezen a hagymaszerű felületen a maximumpontoktól az origó felé eső rész az úgynevezett  Allee-hatás zónája.

sha[7,0.1,0.035,0.025]

Itt a fekete pont az egyensúlyi helyzetet mutatja, amely az Alee-hatás zónájába esik.

sha[10,0.1,0.035,0.08]

Ez a fekete pont (egyensúlyi helyzet) az Allee-hatás zónáján kívül esik, és mindig aszimptotikusan stabils, a Jacobi-mátrix előjelstabilis.

Összegezve (türelem!)

Manipulate[sha[R,0.1,0.035,0.05],{{R,7},3,14,1},SaveDefinitions->True ]

Hivatkozások

Farkas, M.: Dynamical models in biology, Academic Press, New York, 2001.

Kiss, K., Kovács, S.: Qualitative behaviour of n-dimensional ratio-dependent predator-prey systems,
Appl. Math. Comput. 199 (2) (2008), 535–546.