Quit[];

A vérkeringésbe jutott gyógyszer koncentrációja

A jelenség és a modell

A részletesebb leírást Medgyessy legalul megadott cikkéből lehet elolvasni.

A jelenség

(Subscript[V, 1]) térfogatban M tömegű gyógyszert adunk intravénásan. A páciens vérének térfogata (Subscript[V, 2]). A gyógyszer a vérbe áramlik, és a vérből a külvilágba távozhat. A két lépés (felszívódás és kiürülés) sebességére jellemző pozitív számok: K és k. Az érdekel bennünket, hogy hogyan tudjuk meghatározni a diagnosztikai jelentéssel bíró felszívódási és kiürülési sebességet.

A modell

eq={a'[t]== -(K/(Subscript[V, 1]))a[t]+(K/(Subscript[V, 2]))b[t],b'[t]== (K/(Subscript[V, 1]))a[t]-((K+k)/(Subscript[V, 2]))b[t]};ini={a[0]==M,b[0]==0};

f[a_,b_]:=-(K/(Subscript[V, 1]))a+(K/(Subscript[V, 2]))b;g[a_,b_]:=(K/(Subscript[V, 1]))a-((K+k)/(Subscript[V, 2]))b;

eq=={a'[t]==f[a[t],b[t]],b'[t]==g[a[t],b[t]]}

Jelölések

Ahol:

a(t) a gyógyszer tömege a beadás helyén a t időpontban

b(t) a gyógyszer tömege a vérben a t időpontban

(Subscript[V, 1])>0 az injekció térfogata

(Subscript[V, 2])>0 a vér térfogata

K>0 a gyógyszer be- és kiáramlására jellemző diffúziós együttható

k>0 a gyógyszer kiürülésére és lebomlására jellemző diffúziós együttható

M>0 a beadott gyógyszer mennyisége

Kiegészítő magyarázat

a folyamat (farmakokinetikában) szokásos jelölése: A(Underoverscript[⇌, K, K])B(Overscript[->, k])C

a modell számtalan variációja ismert, lásd pl. Jacquez (1996) vagy Karsai (2002).

A direkt feladat megoldása

Ismertnek feltételezve a paramétereket meghatározzuk az egyes rekeszekben (kompartmentekben) a gyógyszer mennyiségét.

Simplify[ds=DSolve[Join[eq,ini],{a[t],b[t]},t]];

(((K M)/((Subscript[V, 1])((Subscript[λ, 2])-(Subscript[λ, 1]))))((E^(-(Subscript[λ, 1])t))-(E^(-(Subscript[λ, 2])t)))/.{(Subscript[λ, i_]):>Root[((K k)/((Subscript[V, 1])(Subscript[V, 2])))-((K/(Subscript[V, 1]))+((K+k)/(Subscript[V, 2]))) #1+((#1)^2)&,i]})/.{t->0}

Reduce[{(b[t]/.ds)==(((K M)/((Subscript[V, 1])((Subscript[λ, 2])-(Subscript[λ, 1]))))((E^(-(Subscript[λ, 1])t))-(E^(-(Subscript[λ, 2])t)))/.{(Subscript[λ, i_]):>Root[((K k)/((Subscript[V, 1])(Subscript[V, 2])))-((K/(Subscript[V, 1]))+((K+k)/(Subscript[V, 2]))) #1+((#1)^2)&,3-i]}),K>0,k>0,(Subscript[V, 1])>0,(Subscript[V, 2])>0},{t},Reals]

A továbbiakban tehát használhatjuk b helyett a fenti alakot:

b[t_]:=((K M)/((Subscript[V, 1])((Subscript[λ, 2])-(Subscript[λ, 1]))))((E^(-(Subscript[λ, 1])t))-(E^(-(Subscript[λ, 2])t)))/.{(Subscript[λ, i_]):>Root[((K k)/((Subscript[V, 1])(Subscript[V, 2])))-((K/(Subscript[V, 1]))+((K+k)/(Subscript[V, 2]))) #1+((#1)^2)&,3-i]}

Az inverz feladat megoldása

Mintavétel

V térfogatú mintát veszünk a vérből, eközben feltételezzük, hogy a gyógyszer eloszlása a teljes vérben homogén:

q[t_]:=(V/(Subscript[V, 2]))b[t]

ahol:

q(t) a gyógyszer tömege a mintában a t időpontban

V>0 a minta térfogata

A paramétereket ebben az igen speciális esetben Medgyessy ötletes módszerével határozzuk meg, általában a legkisebb módszerét szokás alkalmazni, amihez a Mathematica NonlinearModelFit elnevezésű függvénye adhat segítséget.

1. lépés

Adottak a t↦f(t):=B((e^(-(Subscript[λ, 1])t))-(e^(-(Subscript[λ, 2])t))) függvény értékei, határozzuk meg a B, (Subscript[λ, 1]),(Subscript[λ, 2]) paraméterek értékét.

Belátható, hogy f(2t)=f(t)((e^(-(Subscript[λ, 1])t))+(e^(-(Subscript[λ, 2])t))) és f(4t)=f(2t)((e^(-2(Subscript[λ, 1])t))+(e^(-2(Subscript[λ, 2])t))).

Ha tehát a T>0,2T,4T időpontokban mérünk, akkor a ξ:=(e^(-(Subscript[λ, 1])T)) és η:=(e^(-(Subscript[λ, 2])T)) jelőlésekkel azt kapjuk, hogy  ξ+η=((f(2T))/(f(T)))     (ξ^2)+(η^2)=((f(4T))/(f(2T))), azaz a ξ és η pozitív számok egy egyenesszakasz és egy körív metszéspontjaként kaphatók.

Plot[Evaluate[{((f[2T])/(f[T]))-ξ,(Sqrt[((f[4T])/(f[2T]))-(ξ^2)])}/.{f[T]->76,f[2T]->76,f[4T]->55}],{ξ,0,1.3},PlotRange->{0,1.3},AspectRatio->Automatic,AxesLabel->{ξ,η}]

sol=Solve[{ξ+η==((f[2T])/(f[T])),(ξ^2)+(η^2)==((f[4T])/(f[2T]))}/.{f[T]->76,f[2T]->76,f[4T]->55},{ξ,η}]

N[%]

Ha tehát a T>0,2T,4T id[pontokban mérünk, akkor a ξ:=(e^(-(Subscript[λ, 1])T)) és η:=(e^(-(Subscript[λ, 2])T)) jelőlésekkel azt kapjuk, hogy  ξ+η=((f(2T))/(f(T)))     (ξ^2)+(η^2)=((f(4T))/(f(2T))), azaz a ξ és η pozitív számok egy egyenesszakasz és egy körív metszéspontjaként kaphatók.

2. lépés

Ismerve (V/(Subscript[V, 2]))((K M)/((Subscript[V, 1])((Subscript[λ, 2])-(Subscript[λ, 1])))) valamint (Subscript[λ, 1]) és (Subscript[λ, 2]) értékét, a diffúziós együtthatók (és ráadásul a vér téfogata!) meghatározhatók. Legyen T=55 óra.

{(Subscript[λ, 1])=-((Log[ξ])/T)/.{T->55}/.sol[[1]],(Subscript[λ, 2])=-((Log[η])/T)/.{T->55}/.sol[[1]]}//N

Adottak a t↦f(t):=B((e^(-(Subscript[λ, 1])t))-(e^(-(Subscript[λ, 2])t))) függvény értékei, határozzuk meg a B, (Subscript[λ, 1]),(Subscript[λ, 2]) paraméterek értékét. Az alábbi redundáns számolás ellenőrzésre is alkalmas.

B={((f[T])/((E^(-(Subscript[λ, 1])T))-(E^(-(Subscript[λ, 2])T)))),((f[2T])/((E^(-(Subscript[λ, 1])2T))-(E^(-(Subscript[λ, 2])2T)))),((f[4T])/((E^(-(Subscript[λ, 1])4T))-(E^(-(Subscript[λ, 2])4T))))}/.{f[T]->76,f[2T]->76,f[4T]->55}/.{T->55}/.sol[[1]]//N

Solve[(V/(Subscript[V, 2]))((K M)/((Subscript[V, 1])((Subscript[λ, 2])-(Subscript[λ, 1]))))==B[[1]],(Subscript[V, 2])][[1]]//Quiet

Egyetlen lépést hagyunk az olvasóra: meghatározandó még (Subscript[λ, 1]) és (Subscript[λ, 2]) ismeretében K (és k) értéke.

Diagnosztikai alkalmazás

Tegyük fel, hogy megmértünk sok egészséges és beteg pácienst, és a követekező diffúzis együtthatókat kaptuk:

SeedRandom[100];egeszseges=Array[{RandomReal[NormalDistribution[0.2,0.1]],RandomReal[NormalDistribution[0.5,0.5]]}&,22];
beteg=Array[{RandomReal[NormalDistribution[1.2,0.8]],RandomReal[NormalDistribution[0.2,0.2
3]]}&,12];

p[{a_,b_},szin_:Red]:={szin,PointSize[Large],Point[{a,b}]}

s1=Show[Graphics[p/@egeszseges],Graphics[p[#,Blue]&/@beteg],PlotLabel->{Style["egészséges",Red],Style["beteg",Blue]},Frame->True ]

Ha érkezik egy következő páciens, akkor két adatának megmérésével azonnal eldönthető, melyik csoportba tartozik.

fc=FindClusters[Join[egeszseges,beteg],2];

s2=Show[Graphics[p[#,Red]&/@fc[[1]]],Graphics[p[#,Blue]&/@fc[[2]]],Frame->True,PlotLabel->"Két osztály" ]

GraphicsRow[{s1,s2},PlotLabel->"Nem teljesen úgy, ahogyan szeretnénk."]

Hivatkozások

Jacquez, J. A.: Compartmental analysis in biology and medicine (Third edition), Thomson Shore Inc., 1996.

Karsai J.: Impulzív jelenségek modelljei. Mathematica kísérletek, TYPOTEX Kiadó, Budapest, 2002. (11. fejezet)

Medgyessy Pál: 6. Hogyan követhetjük a vérkeringésbe jutott gyógyszer koncentrációjának változását?,
In: Tíz példa a matematika gyakorlati alkalmazására, (Csiszár I., Heppes A., Kovács L. B., Medgyessy P., Vincze I.), Gondolat, Budapest, 1967, pp. 117–133.

Rácz I.; Gyarmati L.; Tóth J.: Hidrofil és lipofil karakterű felületaktív anyagok befolyása a szalicilsav-transzport kinetikájára háromfolyadékteres rendszer esetén, Acta Pharmaceutica Hungarica 47 (1977), 201–208.