Quit[];

A diszkrét idejű exponenciális modell

Farkas Miklós: Dynamical models in biology (Academic Press 2001), 3. old.

A modell

eq=Ν[t+1]== Ν[t](E^(r(1-(( Ν[t])/K))));ini=Ν[0]==Ν0;

Jelölések

ahol:

N(t) a populáció létszáma a t időpontban

r>0 az úgynevezett belső növekedési ráta (azaz születési és a halálozási ráta különbsége)

K>0 a környezet fenntartóképessége

F[Ν_,r_,K_]:=Ν (E^(r(1-(( Ν)/K))))

Plot[F[Ν,.5,3],{Ν,0,30},AxesLabel->{"N","F(N)"}]

Érdekességek

ennek linearizáltja a diszkrét logisztikus modell

Grafikonok

Rögzített paraméterek mellett

Memóriával rendelkező függvénnyel

ClearAll[f];
f[t_]:=f[t]=f[t-1]Exp[0.5(1-((f[t-1])/3))];f[1]=2;

ListPlot[Evaluate[f/@Range[20]],Frame->True,PlotStyle->Directive[{PointSize[Large]}],FrameLabel->{"t","Ν(t)"}]

Változtatható paraméterek mellett

Tessék megpróbálni.

Fix pontok

(N^0):=0 instabilis minden r>0 esetén.

(N^1):=K aszimptotikusan stabilis, ha 0<r<2.

Plot[Evaluate[D[F[Ν,.5,3],Ν]],{Ν,0,30},PlotRange->All,PlotLabel->"F'(3) = "<>ToString[D[F[Ν,.5,3],Ν]/.{Ν->3}]<>"\nF'(0) = "<>ToString[D[F[Ν,.5,3],Ν]/.{Ν->0}],AxesLabel-> {"N","F'(N)"}  ]

Ha az (N^1) fix pontban |F'(K)|<1, akkor ez a fix pont aszimpotikusan stabilis.

Ha az (N^1) fix pontban |F'(K)|>1, akkor ez a fix pont instabilis.

D[F[Ν,r,K],Ν]/.{Ν->K}//Simplify

Az (N^0) fix pontban |F'(0)|>1, ez a fix pont mindig instabilis.

D[F[Ν,r,K],Ν]/.{Ν->0}//Simplify

Reduce[Abs[D[F[Ν,r,K],Ν]/.{Ν->K}//Simplify]<1,r,Reals]

Tehát ebben az intervallumban stabilis a K egyensúlyi helyzet.

Perióduskettőző bifurkáció

Exponential[r_,K_:1]:=Function[Ν,Ν (E^(r(1-(Ν/K))))]

Orbit[map_,Ν0_,n_]:=NestList[map,Ν0,n];
IterativeProcess[map_,Ν0_,{min_,max_},opts___]:=Module[{fr,orb},orb=Orbit[map,Ν0,50];
fr=MapThread[Line[{{#1,#1},{#1,#2},{#2,#2}}]&,{Drop[orb,-1],Drop[orb,1]}];Show[Plot[{map[Ν],Ν},{Ν,min,max},opts],Graphics[{fr}]]]

abrapar[r_,cimke___]:=GraphicsRow[{ListPlot[Orbit[Exponential[r],0.1,100],AxesLabel->{"r","(SuperStar[Ν])"},PlotLabel->cimke<>"\nr = "<>ToString[r]],IterativeProcess[Exponential[r],0.1,{0,3},AxesLabel->{"Ν","\!\(\*SuperscriptBox["ΝE", 
RowBox[{
StyleBox["r",
FontSlant->"Italic"], 
RowBox[{"(", 
RowBox[{"1", "-", 
StyleBox[FractionBox[
StyleBox["N",
FontSlant->"Italic"], "K"],
FontSlant->"Italic"]}], ")"}]}]]\)"},PlotLabel->"r = "<>ToString[r]]},ImageSize->600]

abrapar[1.9,"Aszimptotikusan stabilis\n egyensúlyi helyzet"]

abrapar[2.0,"2 periódusú pálya"]

abrapar[2.2]

abrapar[2.53,"4 periódusú pálya"]

abrapar[2.65]

abrapar[3.1,"3 periódusú pálya,\nebből lesz káosz"]

abrapar[3.3]

Manipulate[abrapar[r],{{r,1.8},0,3.3,0.01},SaveDefinitions->True]

A modell előnyei

figyelembe veszi, hogy a zsúfoltság és a véges mennyiségű táplálék miatt a populáció nem növekszik korlátlanul

N(t)>0, ha (Subscript[N, 0])>0

tipikusan rovarpopulációk modellezésére alkalmas

A modell hátrányai

a modell determinisztikus

Hivatkozások

Feigenbaum, M. J.: Quantitative universality for a class of non-linear transformations, J. Stat. Phys. 19 (1978), 25–52.

Gutierrez, J. M.; Iglesias, A.: Mathematica package for analysis and control of chaos in nonlinear systems, Computers in Physics 12 (6) (1998), 608–619.

May, R. M.: Nagyon bonyolult dinamikájú egyszerű matematikai modellek, Alk. Mat. Lapok 8 (1982), 427-446. (fordította Turányi Tamás, az eredeti cikk adatai: Simple mathematical models with very complicated dynamics, Nature 261 (1976) 459–467. )